// ask which columns are involved

dlg = Column Dialog(

      Title( "Two-Sample t-Test" ),

      yCol = Col List( "Samples",

            Data Type( Numeric ),

            Min Col( 2 ),

            Max Col( 2 )

      ),

      "Select two columns"

);

 

If( dlg["Button"] == -1,

      Throw ( "User cancelled" )

);

 

Remove From( dlg );

Eval List( dlg );

 

colExpr = Expr( Columns() );

Insert Into(

      colExpr,

      yCol[1]

);

Insert Into(

      colExpr,

      yCol[2]

);

 

dt = Eval(

      Substitute(

            Expr(

                  Current Data Table() << Stack(

                        ccc,

                        Source Label Column( "Sample" ),

                        Stacked Data Column( "Response" ),

                        Output Table( "Two-Sample Test" )

                  )

            ),

            Expr( ccc ),

            Name Expr( colExpr )

      )

);

 

dt << Oneway(

      Y( :Response ),

      X( :Sample ),

      t Test( 1 ),

      Box Plots( 0 ),

      Mean Diamonds( 0 )

);